all repos — searchix @ 012318008892a024366f847d0b718210a558c7c2

Search engine for NixOS, nix-darwin, home-manager and NUR users

nix/package.nix (view raw)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
{
  pkgs ? (
    let
      inherit (builtins) fetchTree fromJSON readFile;
      inherit ((fromJSON (readFile ../flake.lock)).nodes) nixpkgs gomod2nix;
    in
    import (fetchTree nixpkgs.locked) {
      overlays = [
        (import "${fetchTree gomod2nix.locked}/overlay.nix")
      ];
    }
  ),
  buildGoApplication ? pkgs.buildGoApplication,
  css,
}:
let
  version = "0.3.0";
in
buildGoApplication {
  pname = "searchix";
  inherit version;
  src =
    with pkgs.lib.fileset;
    toSource {
      root = ../.;
      fileset = difference (unions [
        ../go.mod
        ../go.sum
        ../internal
        ../frontend
        ../cmd
        ../web
      ]) (maybeMissing ../frontend/static/base.css);
    };

  subPackages = [ "cmd/searchix-web" ];

  patchPhase = ''
    rm -f frontend/static/base.css
    cp ${css} frontend/static/base.css
  '';
  tags = [ "embed" ];
  ldflags = [
    "-X"
    "alin.ovh/searchix/internal/config.Version=${version}"
  ];

  postInstall = ''
    install -d -m755 $out/lib/searchix/static
    cp -r $src/frontend/static $out/lib/searchix
    cp ${css} $out/lib/searchix/static/base.css
    $out/bin/searchix-web generate-error-page > $out/lib/searchix/error.html
  '';

  modules = ../gomod2nix.toml;

  doCheck = false;
}