if not set --query SCRIPTURA_ROOT
    if set --query SD_ROOT
        set --global SCRIPTURA_ROOT $SD_ROOT
    else
        set --global SCRIPTURA_ROOT "$HOME/sd"
    end
end

function scriptura
    set --function valid_subcommands run help new edit which cat

    if not path is $SCRIPTURA_ROOT
        if test "$argv[1]" = new
            mkdir $SCRIPTURA_ROOT
            return 0
        else
            echo \$SCRIPTURA_ROOT $SCRIPTURA_ROOT does not exist, use `$(status function) new` to create it
            return 1
        end
    end

    if not count $argv >/dev/null
        __scriptura_usage $valid_subcommands
        return 0
    end

    set --function target $SCRIPTURA_ROOT
    set --function valid 0

    set --function subcommand $argv[1]

    if contains $subcommand $valid_subcommands
        set --erase argv[1]
    else
        echo Invalid subcommand: $subcommand >&2
        echo Expected one of: $valid_subcommands >&2
        return 1
    end

    for i in (seq (count $argv))
        if test "$argv[$i]" = --
            set --function valid $i
            break
        else if path is --type dir $target/$argv[$i]
            set --function target $target/$argv[$i]
            set --function seen_dir 1
            set --function valid $i
        else if path is --type file $target/$argv[$i]; or test "$subcommand" = new
            set --function target $target/$argv[$i]
            set --function seen_script 1
            set --function valid $i
            if not test "$subcommand" = new
                break
            end
        else
            break
        end
    end

    set --local remaining $argv[(math $valid + 1)..-1]

    switch $subcommand
        case run
            if set --query --function seen_script
                __scriptura_run $target $remaining
                return $status
            else if path is --type dir $target;
                and test (count $remaining) -eq 0;
                or set --query --function seen_dir

                __scriptura_list $target
                return $status
            end
        case help
            __scriptura_help $target
            return $status
        case new
            __scriptura_new $target $remaining
            return $status
        case edit
            __scriptura_edit $target $remaining
            return $status
        case which
            __scriptura_which $target $remaining
            return $status
        case cat
            __scriptura_cat $target $remaining
            return $status
    end

    echo "scriptura: don't know what to do with target \"$argv\"" >&2
    return 1
end