{
  config,
  pkgs,
  ...
}:
{
  imports = [
    ../settings/services/caddy.nix
    ../settings/configuration/nur.nix
  ];
  age.secrets = {
    acme.file = ../../secrets/acme.age;
    # TS_AUTHKEY for caddy-tailscale plugin
    caddy.file = ../../secrets/caddy.age;
  };

  security.acme = {
    defaults = {
      email = "security@${config.networking.domain}";
      dnsProvider = "pdns";
      credentialsFile = config.age.secrets.acme.path;
      validMinDays = 32;
    };
    acceptTerms = true;
  };

  services.caddy = {
    environmentFile = config.age.secrets.caddy.path;
    package = pkgs.caddy.withPlugins {
      plugins = [
        "github.com/caddyserver/cache-handler@v0.16.0"
        "github.com/mholt/caddy-l4@v0.0.0-20260212155620-dd12cc413469"
        "github.com/tailscale/caddy-tailscale@v0.0.0-20260106222316-bb080c4414ac"
        "github.com/caddy-dns/rfc2136@v1.0.0"
      ];
      hash = "sha256-SzD72CcYhIMvmgteHI4gyhEU41gExSMEzm1GvxE2ZQY=";
    };
    globalConfig = ''
      cache
      servers {
        listener_wrappers {
          layer4 {
            @ssh ssh
            route @ssh {
              proxy localhost:22
            }
            route
          }
          tls
        }
      }
      tailscale {
        tags tag:app
      }
      acme_dns rfc2136 {
        key_name caddy
        key_alg hmac-sha512
        key "{env.DDNS_TSIG_KEY}"
        server [::1]:53
      }
    '';
  };

  users.groups.caddy.members = [ "alin" ];
  users.groups.webservice = {
    members = [ "caddy" ];
  };
  systemd.tmpfiles.rules = [
    # setgid bit (2)
    # sticky bit (4)
    "d /run/web/ 6770 caddy webservice -"
  ];
  systemd.services.caddy.serviceConfig = {
    ReadWritePaths = [ "/run/web" ];
  };

  boot.kernel.sysctl =
    let
      buffer_size = 16 * 1024 * 1024;
      server_count = 2;
      max_clients = 100;
      page_size = 4096;
      # This server might have 100 clients simultaneously, so:
      #   max(tcp_wmem) * 2 * 100 / 4096
      mem = toString (buffer_size * server_count * max_clients / page_size);
    in
    {
      # Provide adequate buffer memory.
      # rmem_max and wmem_max are TCP max buffer size
      # settable with setsockopt(), in bytes
      # tcp_rmem and tcp_wmem are per socket in bytes.
      # tcp_mem is for all TCP streams, in 4096-byte pages.
      # The following are suggested on IBM's
      # High Performance Computing page
      "net.core.rmem_max" = buffer_size;
      "net.core.wmem_max" = buffer_size;
      "net.core.rmem_default" = buffer_size;
      "net.core.wmem_default" = buffer_size;
      "net.ipv4.tcp_rmem" = "4096 87380 ${toString buffer_size}";
      "net.ipv4.tcp_wmem" = "4096 87380 ${toString buffer_size}";
      "net.ipv4.tcp_mem" = "${mem} ${mem} ${mem}";

      "net.ipv4.tcp_sack" = false;
      "net.ipv4.tcp_dsack" = false;

      "net.ipv4.tcp_slow_start_after_idle" = false;
    };

}