set subcommands -- -l -i -i2 -r -a -p -v \
    --list \
    --interactive \
    --interactive2 \
    --random \
    --add \
    --print-theme \
    --version

complete \
    --command theme.sh \
    --no-files

complete \
    --command theme.sh \
    --condition __fish_is_first_arg \
    --long-option light \
    --exclusive \
    --description "Use light theme filter"

complete \
    --command theme.sh \
    --condition __fish_is_first_arg \
    --long-option dark \
    --exclusive \
    --description "Use dark theme filter"

complete \
    --command theme.sh \
    --short-option l \
    --long-option list \
    --condition "not __fish_seen_subcommand_from $subcommands" \
    --description "Print all available themes"

complete \
    --command theme.sh \
    --short-option i \
    --long-option interactive \
    --condition "not __fish_seen_subcommand_from $subcommands" \
    --description "Start the interactive selection mode (requires fzf)"

complete \
    --command theme.sh \
    --short-option i2 \
    --long-option interactive2 \
    --condition "not __fish_seen_subcommand_from $subcommands" \
    --description "Interactive mode #2 (shows theme immediately)"

complete \
    --command theme.sh \
    --short-option r \
    --long-option random \
    --condition "not __fish_seen_subcommand_from $subcommands" \
    --description "Set a random theme and print its name"

complete \
    --command theme.sh \
    --short-option p \
    --long-option print-theme \
    --condition "not __fish_seen_subcommand_from $subcommands" \
    --description "Attempt to read the current theme from the terminal"

complete \
    --command theme.sh \
    --short-option v \
    --long-option version \
    --condition "not __fish_seen_subcommand_from $subcommands" \
    --description "Print the version and exit"

complete \
    --command theme.sh \
    --short-option a \
    --long-option add \
    --condition "not __fish_seen_subcommand_from $subcommands" \
    --description "Annexes the given kitty config file" \
    --require-parameter

complete \
    --command theme.sh \
    --condition "__fish_seen_subcommand_from -a --add" \
    --force-files

complete \
    --command theme.sh \
    --condition "not __fish_seen_subcommand_from $subcommands --light --dark" \
    --arguments '(theme.sh --list)'

complete \
    --command theme.sh \
    --condition "not __fish_seen_subcommand_from $subcommands" \
    --condition "__fish_seen_subcommand_from --light" \
    --arguments '(theme.sh --light --list)'

complete \
    --command theme.sh \
    --condition "not __fish_seen_subcommand_from $subcommands" \
    --condition "__fish_seen_subcommand_from --dark" \
    --arguments '(theme.sh --dark --list)'