all repos — nixfiles @ fb11451922c8e3542b5b9e341dfd0b4e17023bad

System and user configuration, managed by nix and home-manager

user/settings/development/javascript.nix (view raw)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
{
  config,
  lib,
  pkgs,
  ...
}:
{
  home.packages = with pkgs; [
    typescript-language-server
    vtsls
    biome
  ];

  home.sessionVariables = {
    NO_UPDATE_NOTIFIER = "1"; # stop npm update-notifier
  };

  programs.bun = {
    enable = true;
    settings = {
      run = {
        bun = true;
        silent = true;
      };
      env = false; # don't load .envrc; handled by direnv
      install = {
        prefer = "offline";
        globalDir = "${config.xdg.stateHome}/bun/install/global";
        globalBinDir = "${config.xdg.stateHome}/bun/bin";
        cache = {
          dir = "${config.xdg.cacheHome}/bun/";
        };
      };
    };
  };
  home.sessionPath = lib.mkAfter [
    config.programs.bun.settings.install.globalBinDir
  ];

  programs.emacs.extraPackages =
    epkgs:
    (with epkgs; [
      astro-ts-mode
      svelte-mode
      (treesit-grammars.with-grammars (
        grammars: with grammars; [
          tree-sitter-jsdoc
          tree-sitter-svelte
          tree-sitter-tsx
          tree-sitter-typescript
          tree-sitter-javascript
        ]
      ))
    ]);

  programs.zed-editor = {
    extensions = [
      "biome"
    ];
    userSettings = {
      lsp.biome.settings.require_config_file = true;
      languages =
        let
          justFormatWithBiome = {
            formatter.language_server.name = "biome";
          };
          biomeFormattedLanguages = lib.genAttrs [
            "CSS"
            "HTML"
            "JSON"
            "JSONC"
          ] (lib.const justFormatWithBiome);
        in
        biomeFormattedLanguages
        // rec {
          TypeScript = {
            formatter.language_server.name = "biome";
            code_actions_on_format = {
              "source.fixAll.biome" = true;
              "source.organizeImports.biome" = true;
            };
          };
          TSX = TypeScript;

          JavaScript = TypeScript;
        };
    };
  };

  home.shellAliases = {
    bn = "bun";
    bni = "bun install";
    bna = "bun add";
    bnad = "bun add --dev";
    bnr = "bun run";
    bnu = "bun update";
    bnrm = "bun remove";
    bnd = "bun dev";
    bnp = "bun pm";
    bnl = "bun pm ls";
    bnt = "bun test";
    bntw = "bun test --watch";
    bnx = "bunx";

    np = "npm";
    npi = "npm install";
    npl = "npm ls";
    npr = "npm run";
    npb = "npm run build";
    nprb = "npm run build";
    npa = "npm install --save";
    npad = "npm install --save-dev";
    npd = "npm uninstall";
    npt = "npm test";
    npup = "npm update";
    nppr = "npm prune";
    npprp = "npm prune --production";
    npli = "npm link";
    npul = "npm unlink";
  };

  programs.git.attributes = [
    "*.lockb diff=lockb"
  ];
  programs.git.settings."diff.lockb" = {
    textconv = "bun";
    binary = true;
  };

  xdg.configFile."npm/config".text = ''
    prefix=''${HOME}/.local
    cache=${config.xdg.cacheHome}/npm/
    sign-git-tag=true
    rebuild-bundle=false
    update-notifier=false
    registry=https://registry.npmjs.org/
    @jsr:registry=https://npm.jsr.io
  '';
}