{
  config,
  pkgs,
  ...
}:
{
  services.logind.settings.Login = {
    IdleAction = "poweroff";
    IdleActionSec = "1 hour";
    StopIdleSessionSec = "15 min";
  };

  services.openssh.startWhenNeeded = true;
  systemd.services."ssh-inhibit-idle@" = {
    bindsTo = [ "sshd@%i.service" ];
    wantedBy = [ "sshd@.service" ];
    serviceConfig.ExecStart = ''
      ${pkgs.systemd}/bin/systemd-inhibit \
        --mode block --what idle \
        --who 'ssh session '%I \
        --why 'session still active' \
        ${pkgs.coreutils}/bin/sleep infinity
    '';
  };

  users.groups.laminar = { };
  users.users.laminar = {
    group = "laminar";
    home = "/var/lib/laminar";
    isNormalUser = true;
    createHome = true;
    packages = with pkgs; [
      fishMinimal
      bash
      gnutar
      bzip2
      gzip
      config.programs.git.package
      cached-nix-shell
      nix
      nix-build-uncached
      config.programs.ssh.package
      laminar
      moreutils
      flock
      just
      rsync
      go
    ];
    openssh.authorizedKeys.keys = [
      "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIHeFYWByDp3lurxzYbQPiMJfHcFEDUdj3TAu5ib2Sv1A laminar@smrk.alin.ovh"
    ];
  };
}