self: super: {
  emacsPackagesFor = emacs: (
    (super.emacsPackagesFor emacs).overrideScope (
      eself: esuper:
        esuper // {
          tabnine-capf = super.callPackage ../packages/tabnine-capf.nix {
            inherit eself;
          };
        }
    )
  );
  vimPlugins = super.vimPlugins.extend (final: prev: {
    coc-tabnine =
      let
        inherit (super) tabnine;
      in
      prev.coc-tabnine.overrideAttrs {
        buildInputs = [ tabnine ];

        postFixup = ''
          mkdir -p $target/binaries/${tabnine.version}
          ln -s ${tabnine}/bin/ $target/binaries/${tabnine.version}/${tabnine.passthru.platform}
        '';
      };
  });
  enchant = super.enchant.overrideAttrs (old: {
    configureFlags = old.configureFlags ++ [ "--without-hspell" ]
      # builtins.filter (c: c != "--with-hspell") old.configureFlags
      ++ self.lib.optional super.stdenv.isDarwin "--with-applespell"
    ;
    buildInputs =
      builtins.filter (c: c.name != "hspell") old.buildInputs
      ++ self.lib.optionals super.stdenv.isDarwin (with super.darwin.apple_sdk.frameworks; [ Cocoa ]);
    propagatedBuildInputs = builtins.filter (c: c.name != "hspell") old.propagatedBuildInputs;
  });
}