all repos — nixfiles @ c408e91c8dd06788ec1f2c61ca1f2fdc0df5b4e7

System and user configuration, managed by nix and home-manager

system/roles/video-library.nix (view raw)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
{
  config,
  lib,
  ...
}:
let
  inherit (config.networking) domain fqdn;
  inherit (import ../../data) homenet tailnet;
  upstream = ''
    reverse_proxy localhost:8096 {
      health_uri /health
      health_body Healthy
    }
  '';
in
{
  services.jellyfin = {
    enable = true;
  };

  services.caddy.virtualHosts = {
    "jf.${domain}" = {
      extraConfig = ''
        ${lib.optionalString (domain == homenet) ''
          tls {
            issuer internal {
              ca home
            }
          }
        ''}
        ${upstream}
      '';
    };
    "jf.${tailnet}" = {
      extraConfig = ''
        bind tailscale/jf
        tls {
          get_certificate tailscale
        }
        ${upstream}
      '';
    };
  };

  services.dnsmasq.settings.cname = [
    "jf.${domain},${fqdn}"
  ];
}