all repos — nixfiles @ a532dd67ff224846f99390ff2bd934503f7697a0

System and user configuration, managed by nix and home-manager

system/settings/satoshipay.nix (view raw)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
{ config, pkgs, fetchurl, lib, ... }:

{ virtualisation = {
  docker = let
    daemonConfig = {
      ipv6 = true;
      fixed-cidr-v6 = "fd69:2074:9fcd:b0fd::/64";
      features = {
        buildkit = true;
      };
    };
    in {
      enable = true;
      enableOnBoot = false;
      liveRestore = false;

      extraOptions = "--config-file=${pkgs.writeText "daemon.json" (builtins.toJSON daemonConfig)}";

      autoPrune = {
        enable = true;
        dates = "Mon, 13:00";
      };
    };
  };

  services.mongodb = {
    enable = true;
    replSetName = "rs0";
    dbpath = "/tmp/mongodb";
  };
  systemd.services.mongodb.wantedBy = lib.mkForce  [];
  systemd.timers.mongodb = {
    description = "Delayed startup of MongoDB";
    wantedBy = [ "timers.target" ];
    timerConfig = {
      OnActiveSec = "1 min";
    };
  };
  systemd.services.mongodb-init = {
    description = "Init mongodb replicaset";
    requires = [ "mongodb.service" ];
    script = "${pkgs.mongodb}/bin/mongo --eval 'rs.initiate()'";
  };
  systemd.timers.mongodb-init = {
    wantedBy = [ "timers.target" ];
    timerConfig = {
      OnActiveSec = "2 min";
    };
  };

  services.redis = {
    enable = true;
  };
  systemd.services.redis.wantedBy = lib.mkForce [];
  systemd.timers.redis = {
    description = "Delayed startup of Redis";
    wantedBy = [ "timers.target" ];
    timerConfig = {
      OnActiveSec = "1 min";
    };
  };

  nix.gc.dates = "12:30";
  system.autoUpgrade.dates = "13:05";

  networking.domain = "satoshipay.io";
}