{
  inputs = {
    flake-compatish.url = "github:lillecarl/flake-compatish";
    srvos = {
      url = "github:nix-community/srvos";
    };
    nixos-hardware = {
      url = "github:NixOS/nixos-hardware";
    };
    vpsadminos.url = "github:vpsfreecz/vpsadminos/staging";
    nanopi = {
      url = "github:alinnow/nixos-nanopi";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nixpkgs.follows = "srvos/nixpkgs";
    darwin = {
      url = "github:lnl7/nix-darwin/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    rosetta-builder = {
      url = "github:cpick/nix-rosetta-builder";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    elgit.url = "git+https://git.alin.ovh/elgit?shallow=0";
    mycal.url = "git+https://git.alin.ovh/mycal?shallow=0";
    searchix.url = "git+https://git.alin.ovh/searchix?shallow=0";
    scriptura = {
      url = "git+https://git.alin.ovh/scriptura?shallow=0";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    tg-auth.url = "https://codeberg.org/opia/tg-auth/archive/main.tar.gz";

    minimal-emacs = {
      url = "github:jamescherti/minimal-emacs.d";
      flake = false;
    };
    nixvim = {
      url = "github:nix-community/nixvim";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    agenix = {
      url = "github:ryantm/agenix";
      inputs = {
        nixpkgs.follows = "srvos/nixpkgs";
        darwin.follows = "darwin";
        home-manager.follows = "home-manager";
      };
    };
  };

  outputs =
    inputs:
    with inputs;
    let
      # System types to support.
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "aarch64-darwin"
      ];

      # Helper function to generate an attrset '{ x86_64-linux = f "x86_64-linux"; ... }'.
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;

      mkHomeConfiguration =
        { modules, system }:
        home-manager.lib.homeManagerConfiguration {
          pkgs = import nixpkgs {
            inherit system;
            overlays = [
              agenix.overlays.default
              scriptura.overlays.default
              (self: super: {
                personal = import ./packages/overlay.nix self super;
              })
            ];
          };

          extraSpecialArgs = {
            inherit inputs;
          };

          modules = [
            nixvim.homeModules.nixvim
            scriptura.homeModules.scriptura
          ]
          ++ modules;
        };
    in
    {
      nixosConfigurations = {
        # build with `nixos-rebuild build-image --image-variant iso-installer`
        minimal-iso = nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          modules = [ ./system/hosts/installer.nix ];
        };
        prefect = nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          modules = (
            with nixos-hardware.nixosModules;
            [
              ./system/hosts/prefect.nix
              common-cpu-amd-pstate
              common-cpu-amd-zenpower
              common-pc-ssd
              common-pc
              "${nixos-hardware}/common/gpu/nvidia/ada-lovelace"
            ]
          );
        };
        r5 = nixpkgs.lib.nixosSystem {
          system = "aarch64-linux";
          specialArgs = { inherit inputs; };
          modules = [
            agenix.nixosModules.default
            srvos.nixosModules.server
            nanopi.nixosModules.r5s
            ./system/hosts/r5.nix
            ./system/hosts/r5-hardware.nix
          ];
        };
        smrk = nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          specialArgs = { inherit inputs; };
          modules = [
            srvos.nixosModules.server
            vpsadminos.nixosConfigurations.containerUnstable
            agenix.nixosModules.default
            ./packages/modules/nixos/laminar.nix
            ./system/hosts/smrk.nix
          ];
        };
        buk = nixpkgs.lib.nixosSystem {
          system = "x86_64-linux";
          specialArgs = { inherit inputs; };
          modules = [
            srvos.nixosModules.server
            vpsadminos.nixosConfigurations.containerUnstable
            agenix.nixosModules.default
            ./packages/modules/nixos/laminar.nix
            ./system/hosts/buk.nix
          ];
        };
      };
      darwinConfigurations = {
        marvin = darwin.lib.darwinSystem {
          system = "aarch64-darwin";
          modules = [
            rosetta-builder.darwinModules.default
            srvos.darwinModules.desktop
            ./system/hosts/marvin.nix
          ];
        };
      };
      homeConfigurations = {
        "alin@marvin" = mkHomeConfiguration {
          system = "aarch64-darwin";
          modules = [
            ./user/hosts/marvin.nix
            ./private/ssh.nix
          ];
        };
        "alin@prefect" = mkHomeConfiguration {
          system = "x86_64-linux";
          modules = [
            ./user/hosts/prefect.nix
            ./private/ssh.nix
          ];
        };
        "alin@r5" = mkHomeConfiguration {
          system = "aarch64-linux";
          modules = [
            ./user/hosts/r5.nix
          ];
        };
        "alin@smrk" = mkHomeConfiguration {
          system = "x86_64-linux";
          modules = [
            ./user/hosts/server.nix
            {
              home.stateVersion = "25.11";
            }
          ];
        };
        "alin@buk" = mkHomeConfiguration {
          system = "x86_64-linux";
          modules = [
            ./user/hosts/server.nix
            {
              home.stateVersion = "25.11";
            }
          ];
        };
      };

      devShells = forAllSystems (
        system:
        let
          pkgs = import nixpkgs { inherit system; };
        in
        {
          default = pkgs.mkShellNoCC {
            packages = with pkgs; [
              just
              nh
              nixos-option
              vpsfree-client
            ];
          };
          secrets = pkgs.mkShellNoCC {
            packages = [ agenix.packages.${system}.default ];
          };
        }
      );
    };
}