all repos — homestead @ main

Code for my website

flake.nix (view raw)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
{
  description = "My website, alanpearce.eu";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  inputs.utils.url = "github:numtide/flake-utils";
  inputs.gomod2nix.url = "github:nix-community/gomod2nix";
  inputs.gomod2nix.inputs.nixpkgs.follows = "nixpkgs";
  inputs.gomod2nix.inputs.flake-utils.follows = "utils";
  inputs.pre-commit-hooks.url = "github:cachix/pre-commit-hooks.nix";
  inputs.pre-commit-hooks.inputs.nixpkgs.follows = "nixpkgs";

  outputs = { self, nixpkgs, utils, pre-commit-hooks, gomod2nix, ... }:
    utils.lib.eachDefaultSystem
      (system:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [
              gomod2nix.overlays.default
            ];
          };
          commonShellPackages = with pkgs; [
            go
            hyperlink
            just
            ko
            flyctl
            redis
            sqlc
          ];
          devPackages = with pkgs; [
            wgo
            gopls
            gotools
            gomod2nix.legacyPackages.${system}.gomod2nix

            systemfd
            modd
          ];
        in
        {
          devShells = {
            ci = pkgs.mkShell {
              packages = commonShellPackages;
            };
            default = pkgs.mkShell {
              inherit (self.checks.${system}.pre-commit-check) shellHook;
              packages = devPackages ++ commonShellPackages;
            };
          };
          checks = {
            pre-commit-check = pre-commit-hooks.lib.${system}.run {
              src = ./.;
              hooks = {
                go-mod-tidy = {
                  enable = true;
                  name = "go-mod-tidy";
                  description = "Run `go mod tidy`";
                  types_or = [ "go" "go-mod" ];
                  entry = "${pkgs.go}/bin/go mod tidy";
                  pass_filenames = false;
                };
                golines.enable = true;
                golangci-lint.enable = true;
                gotest.enable = true;
                govet.enable = true;
                gomod2nix = {
                  enable = true;
                  name = "gomod2nix";
                  description = "Import go.mod updates to nix";
                  types_or = [ "go-sum" ];
                  entry = "${pkgs.gomod2nix}/bin/gomod2nix";
                  pass_filenames = false;
                };
                sqlc = {
                  enable = true;
                  name = "sqlc";
                  description = "Generate go code from SQL";
                  types_or = [ "sql" ];
                  entry = "${pkgs.sqlc}/bin/sqlc generate";
                  pass_filenames = false;
                };
              };
            };
          };
          packages = {
            build = pkgs.buildGoApplication {
              pname = "build";
              version = self.shortRev or self.dirtyShortRev;
              src = ./.;
              modules = ./gomod2nix.toml;
              subPackages = [ "domain/content/builder/build" ];
              nativeBuildInputs = with pkgs; [ makeWrapper ];

              postInstall = ''
                wrapProgram $out/bin/build --set KO_DATA_PATH ${./kodata}
              '';
            };
          };
        });
}