#!/usr/bin/env nix
#!nix develop ``.#ci`` --command just --justfile

docker_registry := "codeberg.org/alinnow/homestead"
docker-tag := env("DOCKER_TAG", `date -u +%Y%m%d%H%M%S` + "-" + `git rev-parse --short HEAD`)
listen_address := env("SERVER_LISTEN_ADDRESS", "::1")
port := env("SERVER_PORT", "8080")
website_repo := env("SOURCE", "../website")

default:
    @just --list --justfile {{ justfile() }} --unsorted

clean:
    rm -fr public

check-links: (build-site "--compress=false")
    hyperlink public --sources {{ website_repo }}

update-all:
    nix flake update
    go get -u

build:
    go build ./domain/content/builder/build

build-site *BUILD_FLAGS: build
    SOURCE={{ website_repo }} ./build {{ BUILD_FLAGS }}

run: dev

dev:
    systemfd -s http::{{ listen_address }}:{{ port }} -- modd

vulncheck:
    govulncheck ./...

ci: check-links

cd *DEPLOY_FLAGS: && (deploy DEPLOY_FLAGS)
    # TODO make idempotent
    # test -n "$CODEBERG_TOKEN" && ko login codeberg.org --username alinnow --password $CODEBERG_TOKEN

container-build:
    KO_DOCKER_REPO={{ docker_registry }} ko build --sbom none --bare --tags {{ docker-tag }} .

deploy *DEPLOY_FLAGS:
    # TODO package danube cli
    danube rapids update --image $(just container-build) homestead {{ DEPLOY_FLAGS }}